# Looking for a Group Budget solution
**URL:** https://community.tiller.com/t/looking-for-a-group-budget-solution/28105
**Category:** Google Sheets
**Created:** [September 9, 2024, 4:48pm UTC](https://community.tiller.com/t/looking-for-a-group-budget-solution/28105 "2024-09-09T16:48:26Z")
**Posts on this page:** 10
**Page:** 1
### Author:  [@mu3484343](https://community.tiller.com/u/mu3484343)
#### Post date: [September 9, 2024, 4:48pm UTC](https://community.tiller.com/t/looking-for-a-group-budget-solution/28105/1 "2024-09-09T16:48:26Z")
I’m trying to figure out how I can have a Group budget, or something that has a similar outcome. I’ve seen [one other thread](https://community.tiller.com/t/creating-budgets-for-groups/8581) about this, but the solution did not seem to address what I’m looking to do.
Food is the perfect Group example for this. Say I’d like to set aside $1,000/mo for anything related to food - that would include Groceries, Restaurants, Fast Food. However, Each of the category amounts fluctuate each month so setting individual budgets for each isn’t really feasible. Instead, setting the Food Group budget to $1,000/mo would give me flexibility to spend in those categories however we’d like, while still respecting that $1,000 Group budget between those 3 categories.
Tracking actual spending in Groceries, Restaurants, etc (i.e. the Categories) is important, but the budget would ideally just be the Food Group holding them all. I’ve tried a few things, but since the Savings Budget and Budgeting in general is built around the Categories sheet, with budgets set there, and there doesn’t seem to be a way to have a Group budget on that sheet, I can’t figure this out.
---
### Author:  [@dmetiller](https://community.tiller.com/u/dmetiller)
#### Post date: [September 9, 2024, 7:54pm UTC](https://community.tiller.com/t/looking-for-a-group-budget-solution/28105/2 "2024-09-09T19:54:26Z")
What if you set Food as the category and then use Groceries, Restaurants, Fast Food as tags? You’d just tag anything in the Food category with the appropriate tag. That way you’d have the budget for the category, and you could still differentiate spending within that category.
---
### Author:  [@mu3484343](https://community.tiller.com/u/mu3484343)
#### Post date: [September 9, 2024, 8:18pm UTC](https://community.tiller.com/t/looking-for-a-group-budget-solution/28105/3 "2024-09-09T20:18:27Z")
Thanks for the suggestion. That’s an easy enough solution to implement, the issue with that though is seeing the breakdown in many sheets that don’t have tag functionality built in and rely on Groups and Categories. Savings Budget for example, or Profit and Loss.
---
### Author:  [@dmetiller](https://community.tiller.com/u/dmetiller)
#### Post date: [September 9, 2024, 8:26pm UTC](https://community.tiller.com/t/looking-for-a-group-budget-solution/28105/4 "2024-09-09T20:26:37Z")
True. I find both [Tags Report](https://community.tiller.com/t/docs-tags-report-for-transaction-tagging/375) and [Transaction Tracker](https://community.tiller.com/t/transaction-tracker-for-google-sheets/12969) to be very handy and easy-to-use tools for keep track of spending by tags. But obviously that doesn’t work if you want everything on one sheet.
---
### Author:  [@Mark.S](https://community.tiller.com/u/Mark.S)
#### Post date: [September 9, 2024, 9:26pm UTC](https://community.tiller.com/t/looking-for-a-group-budget-solution/28105/5 "2024-09-09T21:26:26Z")
How about using a Food Budget category to set the budget and then treat a budget of zero to mean no budget that just always reports zero available so it isn’t flagged over-budget?
Here’s a suggestion for the Monthly Budget sheet, where if the Category contains keyword `Budget`, available is also set to zero.
Categories sheet:
Monthly Budget sheet:
Monthly Budget cell `H16` formula addition:
`if((F16:F=0)+(ISNUMBER(FIND("Budget",B16:B))),0,`
Cell `H16` Before:
```auto
=arrayformula(if(isblank(B16:B),iferror(1/0),if(counta($N$16:$N)=2,if(row($G16:$G)-row($G$16)>=max($N$16:$N),F16:F-G16:G,G16:G-F16:F),if($Q$16="Income",G16:G-F16:F,F16:F-G16:G))))
```
Cell `H16` After:
```auto
=arrayformula(if(isblank(B16:B),iferror(1/0),if((F16:F=0)+(ISNUMBER(FIND("Budget",B16:B))),0,if(counta($N$16:$N)=2,if(row($G16:$G)-row($G$16)>=max($N$16:$N),F16:F-G16:G,G16:G-F16:F),if($Q$16="Income",G16:G-F16:F,F16:F-G16:G)))))
```
---
### Author:  [@mu3484343](https://community.tiller.com/u/mu3484343)
#### Post date: [September 10, 2024, 4:19am UTC](https://community.tiller.com/t/looking-for-a-group-budget-solution/28105/6 "2024-09-10T04:19:10Z")
Thanks for the suggestion. Trying to figure out if I can integrate this into the Savings Budget.
---
### Author:  [@Mark.S](https://community.tiller.com/u/Mark.S)
#### Post date: [September 10, 2024, 1:09pm UTC](https://community.tiller.com/t/looking-for-a-group-budget-solution/28105/7 "2024-09-10T13:09:43Z")
I don’t use the Savings Budget, but I’ll take a peek at it 🧐
---
### Author:  [@Mark.S](https://community.tiller.com/u/Mark.S)
#### Post date: [September 10, 2024, 6:01pm UTC](https://community.tiller.com/t/looking-for-a-group-budget-solution/28105/8 "2024-09-10T18:01:33Z")
Here’s the equivalent/similar change to the Savings Budget.
Savings Budget cell `H12` addition after `IF(N12:N="Category",`:
`IF((E12:E=0)+(ISNUMBER(FIND("Budget",B12:B))),0,`
Cell `H12` Before:
```auto
=ARRAYFORMULA(IF(N12:N="Category",VLOOKUP(B12:B,{$AE$11:$AE,$AR$11:$AR},2,FALSE),IF(N12:N="Type",SUMIF($AF$11:$AF&$AH$11:$AH,B12:B,$AR$11:$AR),IF(ISBLANK(N12:N),IFERROR(1/0),SUMIF($AF$11:$AF&$AG$11:$AG&$AH$11:$AH,N12:N&B12:B,$AR$11:$AR)))))
```
Cell `H12` After:
```auto
=ARRAYFORMULA(IF(N12:N="Category",IF((E12:E=0)+(ISNUMBER(FIND("Budget",B12:B))),0,VLOOKUP(B12:B,{$AE$11:$AE,$AR$11:$AR},2,FALSE)),IF(N12:N="Type",SUMIF($AF$11:$AF&$AH$11:$AH,B12:B,$AR$11:$AR),IF(ISBLANK(N12:N),IFERROR(1/0),SUMIF($AF$11:$AF&$AG$11:$AG&$AH$11:$AH,N12:N&B12:B,$AR$11:$AR)))))
```
To remove the sparkline in the `PROGRESS` column for `BUDGET=0`.
Cell `G12` outer IF-block addition:
`IF(E12=0,,`
Cell `E12` Before:
```auto
=IFERROR(
IF(or(O12="Expense",N12="Expense",and(N12="Type",B12="EXPENSE")),
IF(F12+1<=E12+D12,
SPARKLINE({if(isblank(F12),0,F12)},{"charttype","bar";"max",E12+D12;"color1","#2e86de"}),
SPARKLINE({max(0,E12+D12),F12-E12-D12},{"charttype","bar";"max",F12;"color1","#69c569";"color2","#de4c60"})),
IF(or(O12="Income",N12="Income",and(N12="Type",B12="INCOME")),
IF(F12<=E12-D12,
SPARKLINE({if(isblank(F12),0,F12),E12-D12-F12},{"charttype","bar";"max",E12-D12;"color1","#2e86de";"color2","#de4c60"}),
SPARKLINE(F12,{"charttype","bar";"max",F12;"color1","#69c569"})),
IFERROR(1/0))))
```
Cell `E12` After:
```auto
=IFERROR(
IF(E12=0,,
IF(or(O12="Expense",N12="Expense",and(N12="Type",B12="EXPENSE")),
IF(F12+1<=E12+D12,
SPARKLINE({if(isblank(F12),0,F12)},{"charttype","bar";"max",E12+D12;"color1","#2e86de"}),
SPARKLINE({max(0,E12+D12),F12-E12-D12},{"charttype","bar";"max",F12;"color1","#69c569";"color2","#de4c60"})),
IF(or(O12="Income",N12="Income",and(N12="Type",B12="INCOME")),
IF(F12<=E12-D12,
SPARKLINE({if(isblank(F12),0,F12),E12-D12-F12},{"charttype","bar";"max",E12-D12;"color1","#2e86de";"color2","#de4c60"}),
SPARKLINE(F12,{"charttype","bar";"max",F12;"color1","#69c569"})),
IFERROR(1/0)))))
```
The cell `E12` formula change would need to be copied down to the end of column E, since it is not an ARRAYFORMULA and cell has it’s own formula.
---
### Author:  [@LoveExcel](https://community.tiller.com/u/LoveExcel)
#### Post date: [October 22, 2025, 4:16am UTC](https://community.tiller.com/t/looking-for-a-group-budget-solution/28105/9 "2025-10-22T04:16:29Z")
Curious if you found a solution for this?
---
### Author:  [@twalane](https://community.tiller.com/u/twalane)
#### Post date: [October 28, 2025, 4:20pm UTC](https://community.tiller.com/t/looking-for-a-group-budget-solution/28105/10 "2025-10-28T16:20:47Z")
@LoveExcel sharing here as well in case someone else comes looking via this thread, I think the [Budget Rollup Report](https://community.tiller.com/t/docs-category-rollup-report/121#p-288-budget-period-rollup-report-6) is a good option.